Log inRegister an accountBrowse CSDbHelp & documentationFacts & StatisticsThe forumsAvailable RSS-feeds on CSDbSupport CSDb Commodore 64 Scene Database
You are not logged in - nap
CSDb User Forums


Forums > C64 Coding > NEOS mouse, losing my hair...
2018-09-30 11:57
jamiefuller
Account closed

Registered: Mar 2018
Posts: 25
NEOS mouse, losing my hair...

Hi All,

Please can anyone help, I am trying to read the signal from the NEOS mouse, I have this bit working based on some code from the c64-wiki and a working mouse pointer.
But no matter what I do it massively interferes with the keyboard.

I have heard the mouse works with GEOS so it must be theoretically possible (unless the NEOS only works with GEOS in joystick mode).

The source code is below and also on pastebin, I've tried to make it as readable as possible but my code isn't always the tidiest. :)

https://pastebin.com/SSbUbvhx

basically it runs every frame to poll the mouse, it puts the values into some variables (set to the screen in this example to make it visible)

the background colour should only change if the W key is being pressed, but it triggers even when not pressing due to the mouse.

Would be grateful of any advice.

Thanks
Jamie


VIC_SPRITE_MSB=$D010
VIC_SPRITE_ENABLE=$D015
VIC_SPRITE_YEXPAND=$D017
VIC_SPRITE_PRIORITY=$D01B
VIC_SPRITE_MULTICOLOUR=$D01C
VIC_SPRITE_XEXPAND=$D01D
VIC_BORDERCOLOUR=$D020
VIC_BGCOLOUR=   $D021
VIC_BGCOLOUR_MC1=$D022
VIC_BGCOLOUR_MC2=$D023

VIC_SPRITE_MC1= $D025
VIC_SPRITE_MC2= $D026

CIA_1  =        $dc00            ; CIA#1 (Port Register A)
CIA_2  =        $dc01            ; CIA#2 (Port Register B)

CIA_ddra =      $dc02            ; CIA#1 (Data Direction Register A)
CIA_ddrb =      $dc03            ; CIA#2 (Data Direction Register B)
XPADDLE=        $d419
MOUSEX=         $0400
MOUSEY=         $0401
MOUSEX_SPEED=   $0428 ;$19
MOUSEY_SPEED=   $0429 ;$1a
MDBUTTON=       $0459

; 10 SYS2064

*=$0801

        BYTE    $0B, $08, $0A, $00, $9E, $32, $30, $36, $34, $00, $00, $00



*=$0810



init    

        ; copy sprite data to sprite location
        ldy     #$3F
@in10   lda     spritedata,y
        sta     $0340,y
        dey
        bpl     @in10

        lda     #$0D    ;set sprite pointer
        sta     $07F8
        lda     #$01    ;switch on sprite 1
        sta     VIC_SPRITE_ENABLE
        lda     #$07    ;set sprite colour to yellow
        sta     $D027


        lda     #%01111111
        sta     $DC0D       ;"Switch off" interrupts signals from CIA-1
        and     $D011
        sta     $D011       ;Clear most significant bit in VIC's raster register

        lda     #$51         
        sta     $D012       ; set raster to occour 1 lines down

        lda     #<irq_handler
        sta     $0314       ; set low bit of start
        lda     #>irq_handler
        sta     $0315       ; set high bit of start

        lda     #%00000001
        sta     $D01A
@endloop
        jmp @endloop


irq_handler
        LDA     #$00
        STA     VIC_BORDERCOLOUR
        jsr     handlekeyboard
        jsr     handlemouseneos
        JSR     DRAWSPRITE
        INC     VIC_BORDERCOLOUR

        asl     $D019
        JMP     $EA31


DRAWSPRITE
        lda     MOUSEX
        clc
        adc     #$0C
        asl     a
        pha
        bcc     @ds10
        lda     VIC_SPRITE_MSB
        ora     #$01
        bne     @ds20
@ds10   lda     VIC_SPRITE_MSB
        and     #$FE
@ds20   sta     VIC_SPRITE_MSB
        pla
        sta     $D000   ; sprite X
        clc
        lda     MOUSEY
        adc     #$32
        sta     $D001   ; sprite y
        rts





handlekeyboard
        lda     #$0
        sta     CIA_ddra   ;Port A data direction register.
        lda     #$0
        sta     CIA_ddrb   ;Port B data direction register.
@up   
        lda     #%11111101  ;
        sta     CIA_1 
        lda     CIA_2       ; load column information
        and     #%00000010  ; test 'w' key  
        bne     @noup       ; zero flag is not set -> skip next command
        inc     VIC_BGCOLOUR
@noup    
        rts





handlemouseneos
@LC020  jsr     @LC100
        lda     #$00
        bcc     @LC029
        lda     #$02
@LC029  sta     MDBUTTON
        jsr     @LC190
        lda     CIA_2 ; left button
        and     #$10
        BNE     @RT
        INC     MDBUTTON
@RT
        rts

@LC100   ; READ MOUSE
        lda     #$10 
        sta     CIA_ddrb   ;Port B data direction register.
        LDA     #$ef   
        sta     CIA_2   ;PORT B
        lda     CIA_2   ;PORT B, read 4 bits
        asl     a
        asl     a
        asl     a
        asl     a
        sta     MOUSEX_SPEED     ; TIMES BY 16 AND STORE AT $19
        LDA     #$10
        sta     CIA_2
        lda     CIA_2   ; read 4 bits
        and     #$0F
        ora     MOUSEX_SPEED
        sta     MOUSEX_SPEED
        LDA     #$EF
        sta     CIA_2
        lda     CIA_2
        asl     a
        asl     a
        asl     a
        asl     a
        sta     MOUSEY_SPEED
        LDA     #$10
        sta     CIA_2
        lda     CIA_2
        and     #$0F
        ora     MOUSEY_SPEED
        sta     MOUSEY_SPEED
        lda     XPADDLE
        cmp     #$FF
        rts


@LC190   ; TRANSLATE BASED ON SPEED
        lda     MOUSEX_SPEED
        bmi     @LC1A2
        sec
        lda     MOUSEX
        sbc     MOUSEX_SPEED
        bcs     @LC1AF
        lda     #$00
        beq     @LC1AF
@LC1A2  sec
        lda     MOUSEX
        sbc     MOUSEX_SPEED
        bcs     @LC1AD
        cmp     #$A0
        bcc     @LC1AF
@LC1AD  lda     #$9F
@LC1AF  sta     MOUSEX
        lda     MOUSEY_SPEED
        bmi     @LC1C0
        sec
        lda     MOUSEY
        sbc     MOUSEY_SPEED
        bcs     @LC1CD
        lda     #$00
        beq    @LC1CD
@LC1C0  sec
        lda     MOUSEY
        sbc     MOUSEY_SPEED
        bcs     @LC1CB
        cmp     #$C8
        bcc     @LC1CD
@LC1CB  lda     #$C7
@LC1CD  sta     MOUSEY
        rts



spritedata
        byte    $FC,$00,$00,$F0,$00,$00,$F0,$00,$00,$D8,$00,$00,$8C,$00,$00,$86,$00,$00,$03
        bytes   63

 
... 41 posts hidden. Click here to view all posts....
 
2018-09-30 18:41
jamiefuller
Account closed

Registered: Mar 2018
Posts: 25
Quote: Nm, though it was about 1351 only..



:)
2018-09-30 18:46
JackAsser

Registered: Jun 2002
Posts: 1987
Quote: whats there to research for 1351? =D

Alot
2018-09-30 18:53
JackAsser

Registered: Jun 2002
Posts: 1987
Quote: Alot

The three most important realisations that are not so well documented are:

1) polling once per frame is WAY insufficient. At least 100hz to handle swift motion.

2) The SID-ADCs do not have a bit 0 jitter but an additive 0/1 jitter which means you can’t simply mask or shift it away like all reference implementations. A jitter between 15-16 will still jitter after an lsr-operation between 7-8 instead.

3) you helped me here Groepaz and it’s not so well documented (well it is if you know WHIC doc to read ;) ) either which is how long you need to wait after polling the keyboard and setting up the control lines for the mouse. I.e. how often the SID scans.
2018-09-30 19:14
chatGPZ

Registered: Dec 2001
Posts: 11088
Quote:
The SID-ADCs do not have a bit 0 jitter but an additive 0/1 jitter which means you can’t simply mask or shift it away like all reference implementations.

hu? i can assure you that my test code that does just that is rock stable without jitter here. sure your mouse isnt just fubar? or are you using some kind of adapter thing that doesnt work exactly right? :)

that said, the SID ADC counter is exactly as much "jittering" as the system clock. the mouse creates the jitter that you see :)
2018-09-30 19:21
JackAsser

Registered: Jun 2002
Posts: 1987
Quote: Quote:
The SID-ADCs do not have a bit 0 jitter but an additive 0/1 jitter which means you can’t simply mask or shift it away like all reference implementations.

hu? i can assure you that my test code that does just that is rock stable without jitter here. sure your mouse isnt just fubar? or are you using some kind of adapter thing that doesnt work exactly right? :)

that said, the SID ADC counter is exactly as much "jittering" as the system clock. the mouse creates the jitter that you see :)


Hmms ok. I’ve tried with both 1351 and micromys. Both shows the same jitter
2018-09-30 19:29
chatGPZ

Registered: Dec 2001
Posts: 11088
try connecting a paddle - when you dont move it, you'll get a stable value (unless that paddle is really crazy dirty or sth). 1351 dont use a resistor, they wait until they "see" the start of the sampling period, and then pull down the line for a while. and that is not perfectly synced with the c64 (obviously) -> jitter
2018-09-30 19:35
JackAsser

Registered: Jun 2002
Posts: 1987
Quote: try connecting a paddle - when you dont move it, you'll get a stable value (unless that paddle is really crazy dirty or sth). 1351 dont use a resistor, they wait until they "see" the start of the sampling period, and then pull down the line for a while. and that is not perfectly synced with the c64 (obviously) -> jitter

Thanks for the in-depth explanation. Non the less it requires some trickery to filter it out. All 1351 implementations I’ve seen don’t do this.
2018-09-30 19:38
chatGPZ

Registered: Dec 2001
Posts: 11088
because there is no need :) i have never seen a problem that would suggest it at least - the textbook example code works just fine. (even polling at 50Hz works fine if you dont move too fast :=P)
2018-09-30 19:48
JackAsser

Registered: Jun 2002
Posts: 1987
https://youtu.be/Ej5INd5P8yU This has been fixed now but you clearly see the jitter here.
2018-09-30 19:57
chatGPZ

Registered: Dec 2001
Posts: 11088
never seen this in the time i worked on micromys, its just rock stable here =P
Previous - 1 | 2 | 3 | 4 | 5 | 6 - Next
RefreshSubscribe to this thread:

You need to be logged in to post in the forum.

Search the forum:
Search   for   in  
All times are CET.
Search CSDb
Advanced
Users Online
E$G/hOKUtO fOrcE
Enforcer/Deers
Freeze/Blazon
kbs/Pht/Lxt
YTM/Elysium
zscs
Guests online: 260
Top Demos
1 Next Level  (9.8)
2 Mojo  (9.7)
3 Coma Light 13  (9.7)
4 Edge of Disgrace  (9.6)
5 No Bounds  (9.6)
6 Comaland 100%  (9.6)
7 Uncensored  (9.6)
8 The Ghost  (9.6)
9 Wonderland XIV  (9.6)
10 Bromance  (9.6)
Top onefile Demos
1 Party Elk 2  (9.7)
2 Cubic Dream  (9.6)
3 Copper Booze  (9.5)
4 Rainbow Connection  (9.5)
5 TRSAC, Gabber & Pebe..  (9.5)
6 Onscreen 5k  (9.5)
7 Dawnfall V1.1  (9.5)
8 Quadrants  (9.5)
9 Daah, Those Acid Pil..  (9.5)
10 Birth of a Flower  (9.5)
Top Groups
1 Booze Design  (9.3)
2 Nostalgia  (9.3)
3 Oxyron  (9.3)
4 Censor Design  (9.3)
5 Crest  (9.3)
Top Diskmag Editors
1 Jazzcat  (9.4)
2 Magic  (9.4)
3 hedning  (9.2)
4 Newscopy  (9.1)
5 Elwix  (9.1)

Home - Disclaimer
Copyright © No Name 2001-2024
Page generated in: 0.063 sec.