Log inRegister an accountBrowse CSDbHelp & documentationFacts & StatisticsThe forumsAvailable RSS-feeds on CSDbSupport CSDb Commodore 64 Scene Database
  You are not logged in 
Dotty Veil   [2020]

Dotty Veil Released by :
Loonies [web]

Release Date :
23 May 2020

Type :
C64 1K Intro

Released At :
Outline Online 2020

Achievements :
Mixed Competition at Outline Online 2020 :  #4

User rating:**********  10/10 (7 votes)   See votestatistics

Credits :
Code .... Blueberry of Loonies

Download :
http://csdb.dk/getinternalfile.php/199199/DottyVeil-SYS2020.prg (downloads: 196)

Look for downloads on external sites:
 Pokefinder.org


Production Info
Submitted by Magic on 23 May 2020
// "Dotty Veil" by Blueberry / Loonies
// 128 bytes (payload) intro for C64
// For the 128 byte intro compo at Outline Online 2020
//
// Start with SYS 2020
//
// Greetings to all multi-platform sizecoders! :)

.label ValueLow = $FE
.label ValueHigh = $FF

.label ZeroPlace = $20

.label Screen = $3800
.label CharSet = $3000

.label STRIDE = 225
.label STRIDE_DEC = 6
.label BOTTOM_STRIDE = STRIDE - STRIDE_DEC * 24


* = $2020

main:
// X = 0, Y = 0
charset:
txa
asl
asl
asl
beq next
asl
asl
asl
beq char
bcc next
dec ptr
// $A9 is LDA #imm, which eats the first byte of
// "inc ptr". Since ptr is $2035, it is interpreted
// as a harmless AND $20,x.
.byte $A9
next:
inc ptr
char:
lda ptr:CharSetTable-1
dey
sta CharSet,x
sta CharSet+$100,y
inx
bne charset

// Clear Color RAM to black
stx $286
jsr $e544

CopiedToZeroPlace:
.pseudopc ZeroPlace {
FrameLoop:
ldx #STRIDE // Stride
yloop:
txa
axs #STRIDE_DEC

ldy #39
xloop:
txa
adc ValueLow
sta ValueLow
lda ValueHigh
adc #$80
sta ValueHigh
sta screen:Screen,y
sta $D400,y // Make some noise!
dey
bpl xloop

clc
adc modulo:#93
sta ValueHigh
inc modulo

clc
lda #40
adc screen
sta screen
bcc !+
inc screen+1
!:
cpx #BOTTOM_STRIDE
bne yloop

// X = BOTTOM_STRIDE
// Y = -1
copy:
lda CopiedToZeroPlaceEnd-BOTTOM_STRIDE-1,x
sta.z ZeroPlaceEnd-BOTTOM_STRIDE-1,x
cpx #BOTTOM_STRIDE-5
bcc noreg
sta $D012,y
nextreg:
iny
sbc #$20
bcs nextreg
noreg:
dex
bpl copy

jmp FrameLoop

// $D011 = $D7
// $D018 = $EC
// $D020 = 0
// ($D021 = 6)
// $D022 = 2
// $D023 = 14
// $D024 = 10
.byte 10,14,2,$20,$EC,$D7
ZeroPlaceEnd:
}
CopiedToZeroPlaceEnd:

CharSetTable:
.byte $FF,$FF,$FF,$FF,$E7,$C3,$81,$00,$00,$00,$00

.print toHexString(main)
.print toHexString(ptr)
Search CSDb
Advanced
Navigate
Prev - Random - Next
Detailed Info
· Summaries
· User Comments (9)
· Production Notes (1)
Fun Stuff
· Goofs
· Hidden Parts
· Trivia
Forum
· Discuss this release
Info on other sites
· Pouët
Sponsored links
Support CSDb
Help keep CSDb running:



Funding status:




About this site:
CSDb (Commodore 64 Scene Database) is a website which goal is to gather as much information and material about the scene around the commodore 64 computer - the worlds most popular home computer throughout time. Here you can find almost anything which was ever made for the commodore 64, and more is being added every day. As this website is scene related, you can mostly find demos, music and graphics made by the people who made the scene (the sceners), but you can also find a lot of the old classic games here. Try out the search box in the top right corner, or check out the CSDb main page for the latest additions.
Home - Disclaimer
Copyright © No Name 2001-2020
Page generated in: 0.083 sec.