//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
CheckLegalPawn:
/*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

RULES:
~~~~~~
Vertical+1:      Pos+8
Vertical+2:      Pos+16         <--- Only when virgin
CapDia+1:        Pos+7
CapDia+1:        Pos+9
En Passant:      Pos+7          <--- Only when adjacent to fresh pawn opponent (Pos+16)
En Passant:      Pos+9          <--- Only when adjacent to fresh pawn opponent (Pos+16)
Upgrade:         Pos = last line (0-7 / 56-63)

//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
CheckLegalRook:
/*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

RULES:
~~~~~~
Vertical:   Pos+8 x [1-8]
Vertical:   Pos-8 x [1-8]
Horizontal: Pos+1->8
Horizontal: Pos-1->8
Castling:   Pos+2      <--- Only when K & R are virgin
Castling:   Pos-3      <--- Only when K & R are virgin

//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
CheckLegalKing:
/*~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

RULES:
~~~~~~
Pos+1 & Pos-1
pos+7 & pos-7
Pos+8 & Pos-8
pos+9 & pos-9
Castling: Pos-2          <--- Only when K & R are virgin
Castling: Pos+3          <--- Only when K & R are virgin
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*/

//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
// Checks the path between the two horizontal Squares
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

HorizontalLineClearCheck:

    // Find number of squares to check
    lda OldSquare
    sec
    sbc SelectedSquare
    bcs !+
      eor #$ff
      adc #$01
!:  tax

    // Find signed parameter to use in the slope checker
    lda OldSquare
    cmp SelectedSquare
    bcc !+
    lda #$ff
    jmp CheckSlope
!:  lda #$01
    jmp CheckSlope

//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
// Checks the path between the two vertical squares
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

VerticalLineClearCheck:
    // Find number of squares between the squares (absolute)
    lda OldSquare
    sec
    sbc SelectedSquare
    bcs !+
      eor #$ff
      adc #$01
!:  lsr
    lsr
    lsr        // Divide the difference with 8
    tax

    // Find signed parameter to use in the slope checker
    lda OldSquare
    cmp SelectedSquare
    bcc !+
    lda #$f8
    jmp CheckSlope
!:  lda #$08
    jmp CheckSlope

//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
// Checks the path between the two diagonal squares
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

DiagonalLineClearCheck:

    // Check if the move is left or right
    lda OldSquare
    and #%00000111
    sta $02
    lda SelectedSquare
    and #%00000111
    sec
    sbc $02
    bcs !Left+
        eor #$ff
        adc #$01
!Right:  // XPOS SelectedSquare > OldSquare
    tax  // Number of squares to check in X-REG

    // Find if move is up or down
    lda OldSquare
    cmp SelectedSquare
    bcs !RightUp+
!RightDown:
    lda #$07
    jmp CheckSlope
!RightUp:
    lda #$f7
    jmp CheckSlope

!Left:   // XPOS OldSquare > SelectedSquare
    tax  // Number of squares to check in X-REG

    // Find if move is up or down
    lda OldSquare
    cmp SelectedSquare
    bcs !LeftUp+
!LeftDown:
    lda #$09
    jmp CheckSlope
!LeftUp:
    lda #$f9
    jmp CheckSlope


//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
// Routine for checking if squares between two points are empty
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
// Parameters:
//   A- $02 - Loaded with Signed byte for slopecheck:
//     #$01 - Horizontal Right
//     #$ff - Horizontal Left     
//     #$08 - Vertical Down
//     #$f8 - Vertical Up
//     #$07 - Diagonal Down-Left
//     #$09 - Diagonal Down-Right
//     #$f9 - Diagonal Up-Right
//     #$f7 - Diagonal Up-Left
//  X-Reg - Squares to check
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
CheckSlope:
    sta $02    // Parameter = Signed number for slope check

    dex        // Decrease with one square to check
    beq !end+  // If already zero, there was no squares to check

    // Find first square to check
    lda OldSquare
    clc
    adc $02    // Skip first square since it's occupied by the piece in oldsquare
    tay

!loop:
    lda $40,y  // Fetch Square,Y
    beq !+
        sec
        rts
!:  tya
    clc
    adc $02
    tay
    dex
    bne !loop-
!end:
    clc
    rts