DC_IRQ
	pha
	txa
	pha             
	tya
	pha
	
	bit $180D       ; interrupt from timer 1? (bit 6)
	bvc DC_IRQ_	; no, skip.

	lda $1c00       ; Flash LED to make sure irq runs.
	eor #$08
	sta $1c00

DC_IRQ_
        pla
        tay
        pla             
        tax
        pla
        rti

(This code is similar to the one stored in disk ROM)

!pseudopc $0500 {

DriveCode_START
	sei		;Set interrupt flag

	lda #$04	;Set buffer number to #$04 (buffer 4)
	sta $3f		;
	
	lda #$d0	;Set jobcode $d0 (jump)
	sta $04		;$04 = Jobcode for buffer 4
	
	lda #$00	;Set irq timer rates...
	sta $1c04	;
	lda #$80	;These can be altered at any rate
	sta $1c05	;except $1c05 must NOT be #$00
	
	lda #$01	;Set up a random counter to use
	sta $1b		;for test.
		
	cli		;Clear int. flag

	;Outside-irq code here...

	;Turn on rotate motor to allow head movement
	lda $1c00
	ora #$04
	sta $1c00

DC_MoveHead		;Loop location

	lda $1b		;See if counter is negative
	bpl *-2		;Loop back if not.
	
	and #$7f	;Set it back to positive
	sta $1b		;
	
	;Move head outwards...
	lda $1c00
	and #$fd	;Probably not the most
	;ora #$00	;efficient way, but it
	ora #$02	;works ;)
	sta $1c00
	;inc $1c00
	;inc $1c00
	dec $1c00
	dec $1c00

	jmp DC_MoveHead		;Jump back to loop
}

!pseudopc $0700 {

	lda $1c00	;Flash LED
	eor #$08	;
	sta $1c00	;
	
	inc $1b		;Increase the counter.
			;Value in counter will eventually
			;be a negative number, checked
			;by the outside IRQ code.

	lda $1c0c	;erase bit 1 in $1c0c
	and #$fd	;CA2 = %??0 
	sta $1c0c

	ldx $49		;Restore the stack pointer
	txs		;executed from the disk ROM
			;($49 was used to store pointer)

	rts		;Return from job code

DriveCode_END
}