sei
    // Disable/ack all CIA interrupts
    ldx #$7f
    stx $dd0d
    lda $dd0d
    stx $dc0d
    lda $dc0d
    // Bank in all available RAM except IO
    lda #$35
    sta $01

    // Ground NMI
    lda #<NMI_Lock
    sta $fffa
    lda #>NMI_Lock
    sta $fffb       // Set NMI Vector to point to RTI
    ldx #$00
    stx $dd0e	// Stop CIA #2 Timer A
    stx $dd04
    stx $dd05       // Set CIA #2 Timer A to 0 cycles
    inx
    stx $dd0d       // Enable CIA #2 Timer A as NMI source
    lda #$81
    sta $dd0e       // Start Timer A and trigger NMI
    bne *+3
NMI_Lock:
        rti

    // Set IRQ Vector
    lda #<IRQ_Vector.getValue()
    sta $fffe
    lda #>IRQ_Vector.getValue()
    sta $ffff

    // Set Raster Interrupt Compare Value
    lda #Raster_Compare_Value.getValue()
    sta $d012
    lda $d011
    .if (Raster_Compare_Value.getValue()<256) {
        and #%01111111
    } else {
        ora #$80
    }
    sta $d011

    // Ack any pending Raster Compare IRQs (normally not neccessary)
    lda #$01
    sta $d019

    // Enable Raster IRQs
//    lda #$01
    sta $d01a

    // Allow IRQ's
    cli
// async code
async:
    jmp async