// Address for all compiled macros
.var libAddrOffset = $2000

// Address (plus flag) for the compiled macro
.var setColorsUsedAddr = null
// Here comes the proc
.macro setColors() {
  // Store current program address
  .var currentAddr = *
  // Check if macro was used before
  .if (setColorsUsedAddr == null) {
    // Not yet, compile at lib address
    * = libAddrOffset
    // Mark the macro as used and store its address
    .eval setColorsUsedAddr = libAddrOffset
    stx $d020
    sty $d021
    rts
    // Update the library address (for additional macros)
    .eval libAddrOffset = *
  }
  // Restore program address
  * = currentAddr
  // Call the proc
  jsr setColorsUsedAddr
}

// Example: Proc called twice, compiled once
// If not used, won't compile
* = $1000

ldx #2
ldy #4
setColors()

ldx #7
ldy #8
setColors()

jmp *

(C:$100e) d 1000
.C:1000  A2 02       LDX #$02
.C:1002  A0 04       LDY #$04
.C:1004  20 00 20    JSR $2000
.C:1007  A2 07       LDX #$07
.C:1009  A0 08       LDY #$08
.C:100b  20 00 20    JSR $2000
.C:100e  4C 0E 10    JMP $100E
.C:1011  00          BRK

(C:$1029) d 2000
.C:2000  8E 20 D0    STX $D020
.C:2003  8C 21 D0    STY $D021
.C:2006  60          RTS
.C:2007  00          BRK